Tutorial - Ingreso de datos (Cuarta parte) / Envío de datos con botón, multicampo y botón único

El programa que vamos a mostrar a continuación, es uno que permite ingresar un texto en un campo de texto para luego, por medio de un botón mostrarlo por el monitor serial de Processing.

El programa usado es el siguiente

/* PROGRAMA DE PRUEBA DE COMUNICACION SERIAL
     
   El siguiente programa nos ayuda a enviar texto usando un boton para recibirlo el 
   mismo dato por el monitor serial de Processsing

   Autor: Carolina G.
   http://beetlecraft.blogspot.pe/
    
   El siguiente programa es de uso publico, cualquier modificacion o mal uso del mismo que pudiera 
   ocasionar el mal funcionamiento de la plataforma de uso de la misma no es responsabilidad del autor
*/

import controlP5.*; // Importacion de la libreria controlP5
ControlP5 cp5;      // Creacion del objeto cp5 para el ControlP5

String[] cabeceraCT = {"Texto 1", "Texto 2"}; // Cabecera del campo de texto
String dato_1, dato_2; // Dato de almacenamiento del cuadro de texto
 
void setup() {
  size(340, 200); // Porte de la pantalla ancho, alto
  
  PFont fuente = createFont( "arial", 15); // Tamano de la fuente y tipo
  
  cp5 = new ControlP5(this); // Inicializacion de la funcion cp5
  
  int y = 20, espaciamiento = 80; // Variables de almacenamiento de coordenada "y" y espaciamiento
  
  for(String nombre: cabeceraCT){
    cp5.addTextfield(nombre) // Nombre del cuadro de texto
       .setPosition(20, y)   // Ubicacion del boton en la ubicacion x, y
       .setSize(200, 40)     // Tamano del boton ancho, alto
       .setAutoClear(false)  // No se limpia el campo de texto con "Enter"
       .setFont(fuente);     // Fuente del texto
    y += espaciamiento;      // Espaciamiento para el siguiente campo de texto       
  }
  
  cp5.addBang("Enviar")     // Nombre del boton
     .setPosition(240, 100) // Ubicacion del boton en la ubicacion x, y
     .setSize(80, 40)       // Tamano del boton ancho, alto
     .setFont(fuente);      // Fuente del texto
}
 
void draw () {
  background(0); // Color de fondo
}
 
void Enviar() {
  // Lectura del valor obtenido del campo de texto
  dato_1 = cp5.get(Textfield.class, "Texto 1").getText();
  dato_2 = cp5.get(Textfield.class, "Texto 2").getText(); 
  
  println("Texto 1: " + dato_1); // Muestra del dato por monitor serial
  println("Texto 2: " + dato_2); // Muestra del dato por monitor serial
  
  // Borra el cuadro de texto despues de apretar el boton
  cp5.get(Textfield.class, "Texto 1").clear(); 
  cp5.get(Textfield.class, "Texto 2").clear();
}

Los resultados son los siguientes:

Autor: