El siguiente link nos lleva a la página oficial de S4A:
* S4A
En la parte inferior de la página encontrará una opción de descarga del software. Escoja el sistema operativo usado y comience la descarga.
Luego de descargar el archivo comprimido, descomprimirlo en una ubicación que deseemos.
En la ubicación de descarga encontraremos un ícono (como se muestra en la figura) de instalación al que simplemente daremos doble click.
Una vez iniciada la instalación, escogemos el idioma de preferencia, en este caso escogemos "Español".
Una ventana emergente aparecerá dar click en "Siguiente".
En la siguiente ventana necesitaremos aceptar las condiciones de uso del programa, para ello habilitamos dando click "Acepto el acuerdo" y luego damos click en "Siguiente".
En la siguiente ventana escoger el destino de instalación del programa y dar click en "Siguiente".
En la ventana emergente dar click en "Siguiente" y si no deseamos que el ícono aparezca en la ventana de inicio damos click a "No crear una carpeta en el Menú Inicio".
En la siguiente ventana aparecerá la opción de "Crear un ícono en el escritorio" si deseamos tener acceso directo del programa en la ventana principal. Luego, dar click en "Siguiente".
La ventana emergente será la de instalación, en este paso debemos dar click en "Instalar".
En la última ventana damos click en "Finalizar".
Al abrirse el entorno de programación nos fijaremos que en la parte derecha aparecerá un mensaje de "Buscando placa..." en caso no se encuentre conectado el Arduino y no se haya cargado el programa de control en la placa.
Sólo nos queda cargar el programa en la plataforma Arduino para poder comenzar a programar en el S4A. Para ello, podemos buscar el programa en la página de S4A en la parte que indica "Download our firmware from here" o pegar el programa en la parte inferior en el IDE de Arduino.
El programa que debe ser grabado en el Arduino es el siguiente:
// NEW IN VERSION 1.6c (by Jorge Gomez):
// Fixed variable type in pin structure: pin.state should be int, not byte
// Optimized speed of execution while receiving data from computer in readSerialPort()
// NEW IN VERSION 1.6b (by Jorge Gomez):
// Added new structure arduinoPins to hold the pins information:
// - This makes the code easier to read and modify (IMHO)
// - Allows to change the type of pin more easily to meet non standard use of S4A
// - Eliminates the need of having to deal with different kind of index access (ie: states[pin-4])
// - By using an enum to hold all the possible output pin states the code is now more readable
// Changed all functions using old style pin access: configurePins(), resetPins(), readSerialPort(), updateActuator() and sendUpdateActuator()
// Fixed possible overflow every 70 minutes (2e32 us) in pulse() while using micros(). Changed for delayMicroseconds()
// Some minor coding style fixes
// NEW IN VERSION 1.6a (by Jorge Gomez):
// Fixed compatibility with Arduino Leonardo by avoiding the use of timers
// readSerialPort() optimized:
// - created state machine for reading the two bytes of the S4A message
// - updateActuator() is only called if the state is changed
// Memory use optimization
// Cleaning some parts of code
// Avoid using some global variables
// NEW IN VERSION 1.6:
// Refactored reset pins
// Merged code for standard and CR servos
// Merged patch for Leonardo from Peter Mueller (many thanks for this!)
// NEW IN VERSION 1.5:
// Changed pin 8 from standard servo to normal digital output
// NEW IN VERSION 1.4:
// Changed Serial.print() for Serial.write() in ScratchBoardSensorReport function to make it compatible with latest Arduino IDE (1.0)
// NEW IN VERSION 1.3:
// Now it works on GNU/Linux. Also tested with MacOS and Windows 7.
// timer2 set to 20ms, fixing a glitch that made this period unstable in previous versions.
// readSerialport() function optimized.
// pulse() modified so that it receives pulse width as a parameter instead using a global variable.
// updateServoMotors changes its name as a global variable had the same name.
// Some minor fixes.
typedef enum {
input, servomotor, pwm, digital }
pinType;
typedef struct pin {
pinType type; //Type of pin
int state; //State of an output
//byte value; //Value of an input. Not used by now. TODO
};
pin arduinoPins[14]; //Array of struct holding 0-13 pins information
unsigned long lastDataReceivedTime = millis();
void setup()
{
Serial.begin(38400);
Serial.flush();
configurePins();
resetPins();
}
void loop()
{
static unsigned long timerCheckUpdate = millis();
if (millis()-timerCheckUpdate>=20)
{
sendUpdateServomotors();
sendSensorValues();
timerCheckUpdate=millis();
}
readSerialPort();
}
void configurePins()
{
arduinoPins[0].type=input;
arduinoPins[1].type=input;
arduinoPins[2].type=input;
arduinoPins[3].type=input;
arduinoPins[4].type=servomotor;
arduinoPins[5].type=pwm;
arduinoPins[6].type=pwm;
arduinoPins[7].type=servomotor;
arduinoPins[8].type=servomotor;
arduinoPins[9].type=pwm;
arduinoPins[10].type=digital;
arduinoPins[11].type=digital;
arduinoPins[12].type=digital;
arduinoPins[13].type=digital;
}
void resetPins() {
for (byte index=0; index <=13; index++)
{
if (arduinoPins[index].type!=input)
{
pinMode(index, OUTPUT);
if (arduinoPins[index].type==servomotor)
{
arduinoPins[index].state = 255;
servo (index, 255);
}
else
{
arduinoPins[index].state=0;
digitalWrite(index,LOW);
}
}
}
}
void sendSensorValues()
{
unsigned int sensorValues[6], readings[5];
byte sensorIndex;
for (sensorIndex = 0; sensorIndex < 6; sensorIndex++) //for analog sensors, calculate the median of 5 sensor readings in order to avoid variability and power surges
{
for (byte p = 0; p < 5; p++)
readings[p] = analogRead(sensorIndex);
insertionSort(readings, 5); //sort readings
sensorValues[sensorIndex] = readings[2]; //select median reading
}
//send analog sensor values
for (sensorIndex = 0; sensorIndex < 6; sensorIndex++)
ScratchBoardSensorReport(sensorIndex, sensorValues[sensorIndex]);
//send digital sensor values
ScratchBoardSensorReport(6, digitalRead(2)?1023:0);
ScratchBoardSensorReport(7, digitalRead(3)?1023:0);
}
void insertionSort(unsigned int* array, unsigned int n)
{
for (int i = 1; i < n; i++)
for (int j = i; (j > 0) && ( array[j] < array[j-1] ); j--)
swap( array, j, j-1 );
}
void swap(unsigned int* array, unsigned int a, unsigned int b)
{
unsigned int temp = array[a];
array[a] = array[b];
array[b] = temp;
}
void ScratchBoardSensorReport(byte sensor, int value) //PicoBoard protocol, 2 bytes per sensor
{
Serial.write( B10000000
| ((sensor & B1111)<<3)
| ((value>>7) & B111));
Serial.write( value & B1111111);
}
void readSerialPort()
{
byte pin;
int newVal;
static byte actuatorHighByte, actuatorLowByte;
static byte readingSM = 0;
if (Serial.available())
{
if (readingSM == 0)
{
actuatorHighByte = Serial.read();
if (actuatorHighByte >= 128) readingSM = 1;
}
else if (readingSM == 1)
{
actuatorLowByte = Serial.read();
if (actuatorLowByte < 128) readingSM = 2;
else readingSM = 0;
}
if (readingSM == 2)
{
lastDataReceivedTime = millis();
pin = ((actuatorHighByte >> 3) & 0x0F);
newVal = ((actuatorHighByte & 0x07) << 7) | (actuatorLowByte & 0x7F);
if(arduinoPins[pin].state != newVal)
{
arduinoPins[pin].state = newVal;
updateActuator(pin);
}
readingSM = 0;
}
}
else checkScratchDisconnection();
}
void reset() //with xbee module, we need to simulate the setup execution that occurs when a usb connection is opened or closed without this module
{
resetPins(); // reset pins
sendSensorValues(); // protocol handshaking
lastDataReceivedTime = millis();
}
void updateActuator(byte pinNumber)
{
if (arduinoPins[pinNumber].type==digital) digitalWrite(pinNumber, arduinoPins[pinNumber].state);
else if (arduinoPins[pinNumber].type==pwm) analogWrite(pinNumber, arduinoPins[pinNumber].state);
}
void sendUpdateServomotors()
{
for (byte p = 0; p < 10; p++)
if (arduinoPins[p].type == servomotor) servo(p, arduinoPins[p].state);
}
void servo (byte pinNumber, byte angle)
{
if (angle != 255)
pulse(pinNumber, (angle * 10) + 600);
}
void pulse (byte pinNumber, unsigned int pulseWidth)
{
digitalWrite(pinNumber, HIGH);
delayMicroseconds(pulseWidth);
digitalWrite(pinNumber, LOW);
}
void checkScratchDisconnection() //the reset is necessary when using an wireless arduino board (because we need to ensure that arduino isn't waiting the actuators state from Scratch) or when scratch isn't sending information (because is how serial port close is detected)
{
if (millis() - lastDataReceivedTime > 1000) reset(); //reset state if actuators reception timeout = one second
}
Pegamos el código en el IDE como se muestra en la imagen y cargamos el programa.
Autor:
No hay comentarios:
Publicar un comentario